Esta é uma das funções mais importantes e mais utilizadas por quem trabalha com planilhas. Assim, neste artigo ensinamos praticamente tudo sobre como fazer PROCV no Excel. São as melhores práticas.
PROCV é uma função do Excel para pesquisar dados em uma tabela organizada verticalmente, ou seja, com várias colunas.
A função PROCV suporta correspondência aproximada e exata e até curingas (assim como * ?) para correspondências parciais. Os valores de pesquisa devem aparecer na primeira coluna da tabela passada como matriz.
Veja na ilustração abaixo como funciona a dinâmica desta função PROCV passo a passo.
Onde está “Valor Procurado” é o local que colocamos a chave de busca. O resultado é o retorno da função após buscar o valor na matriz, que na imagem acima é uma tabela com 5 colunas.
Vemos que na coluna 1 estão os códigos funcionais, que são as referências da busca. O E-mail está na coluna 3 da matriz, e foi essa a coluna informada na função para a busca.
Caso prefira veja como usar PROCV no Excel pela video-aula em seguida do nosso canal do YouTube (lá tem muito mais para você).
Não deixe de se inscreve no canal e dar aquela força para nós.
Sintaxe da Função PROCV no Excel
=PROCV (valor_procurado, matriz_tabela, núm_índice_coluna, [procurar_intervalo])
- valor_procurado: É o valor buscado na primeira coluna da tabela matriz.
- matriz_tabela: Em seguida define a tabela que será a matriz de busca.
- núm_índice_coluna: Então define a coluna que o resultado será buscado.
- procurar_intervalo: [opcional] VERDADEIRO = valor aproximado (padrão). FALSO = valor exato.
Vimos acima que a fórmula do PROCV no Excel recebe quatro argumentos
O valor_procurado leva em conta a matriz_tabela que é o intervalo de dados verticais buscados.
A primeira coluna de matriz_tabela deve conter os valores de pesquisa a serem buscados. O argumento núm_índice_coluna é o número da coluna em que está o valor a ser buscado, portanto a primeira coluna de matriz_tabela é a coluna 1.
Por fim, a parte procurar_intervalo corresponde ao comportamento que a procura terá. Se procurar_intervalo for VERDADEIRO, O PROCV realizará uma correspondência aproximada.
Se procurar_intervalo for FALSO, então o PROCV realizará uma correspondência exata.
PROCV: “V” é para vertical e é baseado em colunas
O propósito desta função é a busca dados que estão organizados em colunas, ou seja, buscar em tabelas igual a abaixo:
Através do código do produto na coluna B dá para buscar o nome do produto, a quantidade e seu preço. A busca acontecerá em todas as linhas na vertical, considerando assim qual coluna que retornará o resultado.
Exemplo:
=PROCV(11004;B5:E14;3;FALSO) // retorna o valor 2O código 11004 é o valor_procurado, na matriz de B5:E14, está buscando na terceira coluna, representado pelo 3 na fórmula. Assim esse PROCV feito no Excel retorna o valor 2, que é a quantidade deste código de produto.
Se precisar procurar na horizontal é melhor utilizar a função PROCH ou INDICE + CORRESP ou PROCX.
Nosso nosso canal no YouTube falamos sobre todas estas funções.
Ao usar a função PROCV no Excel, tenha em mente que cada coluna na matriz_tabela tem um número, começando da esquerda e aumenta 1 a 1 para cada coluna que está à direita.
Para obter um valor de uma coluna, forneça o número para núm_índice_coluna. Por exemplo, o índice da coluna para a quantidade de produtos na fórmula PROCV acima foi o 3.
Veja abaixo mais um exemplo para tirar qualquer dúvida sobre isso.
O nome está na coluna 2, vemos na fórmula PROCV acima, mas mudando o número da coluna temos as demais informações.
=PROCV(I4;B5:F16;2;FALSO) // retorna o nome
=PROCV(I4;B5:F16;3;FALSO) // retorna o e-mail
=PROCV(I4;B5:F16;4;FALSO) // retorna o departamento
=PROCV(I4;B5:F16;5;FALSO) // retorna a data de admissãoNormalmente, usamos a célula travada nestas funções de PROCV, por exemplo, para a célula I4 seria $I$4 e para a tabela matriz B5:F16 seria $B$5:$F$16. Isto é para evitar que quando a fórmula for copiada para outra célula a referência da busca mude.
Para saber mais sobre como travar ou fixar células no Excel vá neste artigo: Como travar células no Excel – Aprenda a fixar células nas fórmulas.
PROCV sempre busca para a direita
PROCV só pode olhar para a direita. Em outras palavras, você só pode buscar dados à direita da coluna que contém os valores de pesquisa.
Usando o Cod_Func como valor procurado na tabela acima dá para procurar com o PROCV do Excel somente as colunas “Departamento” e “Data Admissão”. Caso queira procurar nome ou e-mail tem que usar outra função.
Recomendamos INDICE + CORRESP ou PROCX para tal.
Quer saber mais sobre PROCX então veja o vídeo abaixo que está no nosso canal do YouTube.
Modos de Correspondência PROCV no Excel
A função PROCV tem dois modos de correspondência, o exato e o aproximado.
Estes dois modos são definidos no quarto argumento da fórmula do PROCV, procurar_intervalo. A palavra “intervalo” neste caso refere-se a “intervalo de valores”, assim quando for VERDADEIRO o PROCV corresponderá a um intervalo de valores em vez de um valor exato. O valor padrão para este argumento é VERDADEIRO, ou seja, se você não colocar nada aqui ele buscará por uma correspondência aproximada. Defina procurar_intervalo para FALSO se deseja a correspondência exata.
=PROCV(valor;matriz;coluna) // correspondência aproximada (padrão)
=PROCV(valor;matriz;coluna;VERDADEIRO) // correspondência aproximada
=PROCV(valor;matriz;coluna;FALSO) // correspondência exataDica: sempre forneça um valor para procurar_intervalo como um lembrete do comportamento esperado.
Você também pode fornecer zero (0) para uma correspondência exata (substituindo o FALSO) e 1 para uma correspondência aproximada (substituindo o VERDADEIRO).
Exemplo de Correspondência Exata
Esta é a forma que você mais utilizará o PROCV no Excel, para uma correspondência exata.
Isso sempre faz sentido quando você tem uma chave exclusiva para usar como valor de busca, por exemplo, o nome do estado na imagem abaixo:
A fórmula do PROCV na célula H5 se baseia então na correspondência exata para trazer a população do estado do Paraná.
=PROCV(H3;B3:E13;2;FALSO) // FALSO = correspondência exataExemplo de correspondência aproximada do procv no Excel
Quando você deseja a melhor correspondência, não necessariamente um valor exato, convém usar o modo aproximado.
Por exemplo, abaixo queremos procurar uma taxa de comissão na tabela H4:I8. Os valores buscados vêm da coluna D. Neste caso, precisamos usar a fórmula PROCV no modo de correspondência aproximada, porque na maioria dos casos uma correspondência exata nunca será encontrada.
Então, a função PROCV em “F4” está configurada para realizar uma correspondência aproximada, definindo o último argumento como VERDADEIRO.
=PROCV(D4;$H$4:$I$8;2;VERDADEIRO) // VERDADEIRO = Correspondência aproximadaO PROCV no Excel verificará os valores na coluna H para o valor de procurado. Se uma correspondência exata for encontrada o PROCV vai usar. Caso contrário, o PROCV “recuará” e fará a correspondência com a linha anterior.
Isso significa que tabela_matriz deve ser classificada em ordem crescente por valor de pesquisa para usar correspondência aproximada. No caso de usar o VERDADEIRO ou omitir o procurar_intervalo , a tabela_matriz deve estar sempre em ordem crescente, por outro lado, se não estiver assim o PROCV poderá retornar resultados incorretos ou inesperados.
Retorna apenas o primeiro valor encontrado
No caso de ter valores de correspondência duplicados, o PROCV encontrará a primeira correspondência e para a busca.
Em seguida, na tela abaixo, o PROCV está configurado para encontrar o preço do produto da cor “Verde”. No sistema existem três linhas com a cor verde e PROCV retorna o preço na primeira linha: R$ 13,00.
=PROCV(E4;$B$4:$C$12;2;FALSO) // retorna 13Caso precise retornar, por exemplo, todos os preços da cor verde o PROCV não é a melhor solução.
Busca por caractere “curinga” no PROCV
A função PROCV no Excel tem suporte à caracteres curingas, o que possibilita realizar uma correspondência parcial em um valor de pesquisa.
Por exemplo, você pode usar PROCV para procurar informações de uma tabela com um valor_procurado parcial e curinga.
Para usar curingas com o PROCV, você deve usar o modo de correspondência exata fornecendo FALSO no quarto argumento.
Veja na tela acima que digitamos as 3 primeiras letras do nome e ele já buscou todas as informações. Assim tivemos uma correspondência parcial usando o “*” como o caractere curinga.
=PROCV($H$3&"*";$B$4:$E$15;1;FALSO) // correspondência parcial com *Usando PROCV com CORRESP no Excel
Dentro da função PROCV no Excel, o argumento núm_índice_coluna normalmente é posto como um número estático.
No entanto, você também pode criar um índice de coluna dinâmico usando a função CORRESP para localizar a coluna necessária conforme o nome desta coluna.
Essa técnica, conhecida como PROCV com CORRESP no Excel, permite que você crie uma pesquisa bidirecional dinâmica, combinando linhas e colunas.
Na tela em seguida, o PROCV está configurado para realizar uma pesquisa com base no nome do produto e no Mês.
=PROCV(H3;$B$4:$E$13;CORRESP(H4;$B$3:$E$3;0);FALSO) // encontra coluna 3O CORRESP vai encontrar a coluna 3, pois é onde está o mês de Fev na tabela.
Quer saber mais sobre CORRESP então veja o vídeo abaixo no nosso canal do YouTube.
PROCV com duas condições ou mais
A função PROCV não trata vários critérios de forma nativa. No entanto, você pode usar uma coluna auxiliar para unir vários campos e usar esses campos como chave de busca dentro do PROCV.
Com isso dá para criar um PROCV com duas condições ou mais. Assim, você pode colocar quantas condições que achar que precisa.
Por exemplo, na tela abaixo, a Coluna B é uma coluna auxiliar (chamada de “chave”) que concatena mês e ano, e ela será a referência para o PROCV com duas condições.
Em primeiro lugar, para fazer a referência, juntamos as colunas C e D.
=C4&D4 // concatenando duas célulasEm seguida fazemos o PROCV para fazer a busca correta.
=PROCV(H3&H4;$B$4:$E$13;4;FALSO) // procv com duas condiçõesComo tratar erro #N/D no PROCV do Excel
Se você usar PROCV no Excel, com certeza encontrará o erro #N/D. O erro #N/D significa “não disponível”.
Por exemplo, na tela abaixo, o valor procurado de código do funcionário “928” não existe na tabela matriz e todas as quatro fórmulas PROCV retornaram #N/D.
Então, o fato deste erro #N/D aparecer é útil porque mostra que algo está errado. Assim a razão para o “não disp” pode ser:
- O item buscado não existe na tabela;
- O valor de pesquisa está incorreto ou contém espaço extra;
- Modo de correspondência é exato, mas deve ser aproximado;
- O intervalo da tabela não foi inserido corretamente;
- Por fim, você está copiando PROCV e a referência da tabela não está travada.
Para que o erro #N/D no Excel não apareça, ou seja, para que retorne um valor alternativo você pode usar umas das duas funções abaixo. Qualquer uma das duas funções em seguida funcionam bem.
=SENÃODISP(PROCV($I$3;$B$4:$F$15;2;FALSO);"Não Encontrado")Usamos como valor alternativo, caso dê o erro “não disp” ou “#N/D” o termo “Não encontrado”.
Mas você pode colocar como vazio, sem nenhuma mensagem, veja como fazer isso na fórmula PROCV abaixo.
=SENÃODISP(PROCV($I$3;$B$4:$F$15;2;FALSO);"") // retorna célula vazia
A outra função que falei, para tratar o erro “não disponível” no Excel é a função SEERRO.
Esta função identifica qualquer erro não somente o “N/D”, assim caso precise saber de um erro específico é melhor usar a SENÃODISP. Mas SEERRO também é uma opção viável. Veja a fórmula SEERRO abaixo
=SEERRO(PROCV($I$3;$B$4:$F$15;2;FALSO);"")Conclusão
Vimos ao longo deste artigo tudo sobre a função PROCV no Excel. Tratamos de todas as possibilidades dela.
É uma artigo completo sobre PROCV. Aliás, PROCV em inglês é VLOOKUP.
Se você usa o office em inglês as funções do Excel também estarão em inglês. As vezes é bem simples a conversão da função Excel do português para o inglês, mas nem sempre é.
VLOOKUP é o mesmo que PROCV e tudo que passei aqui neste artigo vale para o VLOOKUP. Não há diferenças na forma do uso da função.
Espero que este artigo tenha ajuda você. Procurei ensinar o PROCV passo a passo e todos os detalhes desta função.
Tem muita coisa interessante aqui e um conteúdo tão completo assim você não vai achar em qualquer lugar. Só aqui neste blog. Até a próxima.